feat: migrate to SceneDelegate

packages/react-native/Libraries/AppDelegate/RCTAppDelegate.h

@@ -19,8 +19,9 @@
 NS_ASSUME_NONNULL_BEGIN
 
 /**
- * @deprecated RCTAppDelegate is deprecated and will be removed in a future version of React Native. Use
- `RCTReactNativeFactory` instead.
+ * @deprecated RCTAppDelegate is deprecated and will be removed in a future version of React Native. For new apps
+ * using the UIScene lifecycle, prefer `RCTSceneDelegate` or `RCTReactNativeFactory` with a SceneDelegate entrypoint.
+ * For AppDelegate-only apps, use `RCTReactNativeFactory` directly.
  *
  * The RCTAppDelegate is an utility class that implements some base configurations for all the React Native apps.
  * It is not mandatory to use it, but it could simplify your AppDelegate code.
@@ -55,7 +56,7 @@ NS_ASSUME_NONNULL_BEGIN
  *   - (id<RCTTurboModule>)getModuleInstanceFromClass:(Class)moduleClass
  */
 __attribute__((deprecated(
-    "RCTAppDelegate is deprecated and will be removed in a future version of React Native. Use `RCTReactNativeFactory` instead.")))
+    "RCTAppDelegate is deprecated and will be removed in a future version of React Native. For UIScene apps use `RCTSceneDelegate`; otherwise use `RCTReactNativeFactory`.")))
 @interface RCTAppDelegate : RCTDefaultReactNativeFactoryDelegate<UIApplicationDelegate>
 
 /// The window object, used to render the UViewControllers

packages/react-native/Libraries/AppDelegate/RCTDefaultReactNativeFactoryDelegate.mm

@@ -66,7 +66,7 @@ - (RCTColorSpace)defaultColorSpace
 
 - (NSURL *_Nullable)bundleURL
 {
-  [NSException raise:@"RCTAppDelegate::bundleURL not implemented"
+  [NSException raise:@"RCTReactNativeFactoryDelegate::bundleURL not implemented"
               format:@"Subclasses must implement a valid getBundleURL method"];
   return nullptr;
 }

packages/react-native/Libraries/AppDelegate/RCTReactNativeFactory.h

@@ -58,6 +58,14 @@ typedef NS_ENUM(NSInteger, RCTReleaseLevel) { Canary, Experimental, Stable };
 
 @interface RCTReactNativeFactory : NSObject
 
+/**
+ * Bootstrap entrypoints:
+ * - **AppDelegate path**: `startReactNativeWithModuleName:inWindow:launchOptions:` — call from
+ *   `application:didFinishLaunchingWithOptions:` or `RCTAppDelegate`.
+ * - **SceneDelegate path**: `startReactNativeWithModuleName:inWindow:connectionOptions:` — call from
+ *   `scene:willConnectToSession:options:` or `RCTSceneDelegate`.
+ */
+
 - (instancetype)initWithDelegate:(id<RCTReactNativeFactoryDelegate>)delegate;
 
 - (instancetype)initWithDelegate:(id<RCTReactNativeFactoryDelegate>)delegate releaseLevel:(RCTReleaseLevel)releaseLevel;
@@ -73,6 +81,32 @@ typedef NS_ENUM(NSInteger, RCTReleaseLevel) { Canary, Experimental, Stable };
                      initialProperties:(NSDictionary *_Nullable)initialProperties
                          launchOptions:(NSDictionary *_Nullable)launchOptions;
 
+/// This is a SceneDelegate entrypoint method to start a React Native instance with the specified module name, window
+/// and connection options for linking & user activity information. As it's usual for the typical deep-linking use case,
+/// only the first item in URLContexts from connectionOptions will be checked; the same applies to userActivities.
+/// @param moduleName name of the JS module to load
+/// @param window the window to launch in
+/// @param connectionOptions the scene's connection options
+- (void)startReactNativeWithModuleName:(NSString *)moduleName
+                              inWindow:(UIWindow *_Nullable)window
+                     connectionOptions:(UISceneConnectionOptions *_Nullable)connectionOptions;
+
+/// This is a SceneDelegate entrypoint method to start a React Native instance with the specified module name, window
+/// and connection options for linking, initial properties & user activity information. As it's usual for the typical
+/// deep-linking use case, only the first item in URLContexts from connectionOptions will be checked; the same applies
+/// to userActivities.
+/// @param moduleName name of the JS module to load
+/// @param window the window to launch in
+/// @param initialProperties the initial root properties
+/// @param connectionOptions the scene's connection options
+- (void)startReactNativeWithModuleName:(NSString *)moduleName
+                              inWindow:(UIWindow *_Nullable)window
+                     initialProperties:(NSDictionary *_Nullable)initialProperties
+                     connectionOptions:(UISceneConnectionOptions *_Nullable)connectionOptions;
+
+@property (nonatomic, nullable) RCTBridge *bridge
+    __attribute__((deprecated("The bridge is deprecated and will be removed when removing the legacy architecture.")));
+
 #if !defined(RCT_REMOVE_LEGACY_ARCH)
 @property (nonatomic, nullable) RCTSurfacePresenterBridgeAdapter *bridgeAdapter __attribute__((
     deprecated("The bridgeAdapter is deprecated and will be removed when removing the legacy architecture.")));

packages/react-native/Libraries/AppDelegate/RCTReactNativeFactory.mm

@@ -40,6 +40,13 @@ @interface RCTReactNativeFactory () <
     RCTHostDelegate,
     RCTJSRuntimeConfiguratorProtocol,
     RCTTurboModuleManagerDelegate>
+
+/// Adapter for SceneDelegate entrypoint's UISceneConnectionOptions that converts it to the AppDelegate-style
+/// NSDictionary for internal RN needs
+/// @param connectionOptions the scene's connection options
+/// @return an NSDictionary with proper UIApplicationLaunchOptions- keys set to values from connectionOptions
+- (NSDictionary *)convertConnectionOptionsToLaunchOptions:(UISceneConnectionOptions *)connectionOptions;
+
 @end
 
 @implementation RCTReactNativeFactory
@@ -95,6 +102,58 @@ - (void)startReactNativeWithModuleName:(NSString *)moduleName
   [window makeKeyAndVisible];
 }
 
+#pragma mark - UIScene.ConnectionOptions
+
+- (void)startReactNativeWithModuleName:(NSString *)moduleName
+                              inWindow:(UIWindow *_Nullable)window
+                     connectionOptions:(UISceneConnectionOptions *_Nullable)connectionOptions
+{
+  [self startReactNativeWithModuleName:moduleName
+                              inWindow:window
+                     initialProperties:nil
+                         launchOptions:[self convertConnectionOptionsToLaunchOptions:connectionOptions]];
+}
+
+- (void)startReactNativeWithModuleName:(NSString *)moduleName
+                              inWindow:(UIWindow *_Nullable)window
+                     initialProperties:(NSDictionary *_Nullable)initialProperties
+                     connectionOptions:(UISceneConnectionOptions *_Nullable)connectionOptions
+{
+  [self startReactNativeWithModuleName:moduleName
+                              inWindow:window
+                     initialProperties:initialProperties
+                         launchOptions:[self convertConnectionOptionsToLaunchOptions:connectionOptions]];
+}
+
+- (NSDictionary *)convertConnectionOptionsToLaunchOptions:(UISceneConnectionOptions *)connectionOptions
+{
+  NSMutableDictionary *launchOptions = [NSMutableDictionary dictionary];
+
+  // handle launch URL
+  if (connectionOptions.URLContexts.count > 0) {
+    UIOpenURLContext *urlContext = connectionOptions.URLContexts.allObjects.firstObject;
+
+    if (urlContext.URL) {
+      launchOptions[UIApplicationLaunchOptionsURLKey] = urlContext.URL;
+    }
+  }
+
+  // handle user activities
+  if (connectionOptions.userActivities.count > 0) {
+    NSUserActivity *activity = connectionOptions.userActivities.allObjects.firstObject;
+
+    if (activity) {
+      NSMutableDictionary *userActivityDict = [NSMutableDictionary dictionary];
+      userActivityDict[UIApplicationLaunchOptionsUserActivityTypeKey] = activity.activityType;
+      userActivityDict[@"UIApplicationLaunchOptionsUserActivityKey"] = activity;
+
+      launchOptions[UIApplicationLaunchOptionsUserActivityDictionaryKey] = userActivityDict;
+    }
+  }
+
+  return launchOptions;
+}
+
 #pragma mark - RCTUIConfiguratorProtocol
 
 - (RCTColorSpace)defaultColorSpace
@@ -209,6 +268,18 @@ - (void)hostDidStart:(RCTHost *)host
 {
   if ([_delegate respondsToSelector:@selector(hostDidStart:)]) {
     [_delegate hostDidStart:host];
+
+    // check if the application is running with multiple scenes capability enabled in scene manifest (Info.plist),
+    // which is unsupported by RN at the moment, and warn in such case
+    NSDictionary *infoDict = [[NSBundle mainBundle] infoDictionary];
+    NSDictionary *sceneManifest = infoDict ? infoDict[@"UIApplicationSceneManifest"] : nil;
+    BOOL supportsMultipleScenes =
+        sceneManifest ? [sceneManifest[@"UIApplicationSupportsMultipleScenes"] boolValue] : false;
+
+    if (supportsMultipleScenes) {
+      RCTLogWarn(
+          @"RCTReactNativeFactory: (WARNING - UNSUPPORTED RN APP CONFIGURATION) Your application is running with the Info.plist UIApplicationSceneManifest.UIApplicationSupportsMultipleScenes key set to true, which is NOT supported by React Native at the moment. Allowing the user to run multiple windows of a RN application means allowing to run multiple instances of React Native and libraries in the same process, which may cause ALL SORTS OF PROBLEMS in implementations which use singletons or static storage lifetime variables.");
+    }
   }
 }
 

packages/react-native/Libraries/AppDelegate/RCTRootViewFactory.mm

@@ -11,7 +11,6 @@
 #import <React/RCTRootView.h>
 #import <React/RCTUtils.h>
 #import <react/renderer/runtimescheduler/RuntimeScheduler.h>
-#import "RCTAppDelegate.h"
 #import "RCTAppSetupUtils.h"
 
 #if RN_DISABLE_OSS_PLUGIN_HEADER

packages/react-native/Libraries/AppDelegate/RCTSceneDelegate.h

@@ -0,0 +1,104 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import <UIKit/UIKit.h>
+#import "RCTDefaultReactNativeFactoryDelegate.h"
+#import "RCTReactNativeFactory.h"
+#import "RCTRootViewFactory.h"
+
+@protocol RCTBridgeDelegate;
+@protocol RCTComponentViewProtocol;
+@class RCTRootView;
+@class RCTSurfacePresenterBridgeAdapter;
+@protocol RCTDependencyProvider;
+
+NS_ASSUME_NONNULL_BEGIN
+
+/**
+ * Optional utility base class for SceneDelegate-based React Native apps using the UIScene lifecycle.
+ *
+ * For AppDelegate-only apps, use `RCTAppDelegate` or `RCTReactNativeFactory` directly.
+ *
+ * Usage:
+ * 1. Declare `UIApplicationSceneManifest` in Info.plist with your SceneDelegate class.
+ * 2. Subclass `RCTSceneDelegate` and configure it before calling `[super ...]` in
+ *    `scene:willConnectToSession:options:`.
+ *
+ * ```objc
+ * #import <React_RCTAppDelegate/RCTSceneDelegate.h>
+ *
+ * @implementation SceneDelegate
+ *
+ * - (void)scene:(UIScene *)scene
+ *     willConnectToSession:(UISceneSession *)session
+ *                  options:(UISceneConnectionOptions *)connectionOptions
+ * {
+ *   self.moduleName = @"MyApp"; // required: JS module name registered in AppRegistry
+ *   self.initialProps = @{
+ *     // optional root props
+ *   };
+ *   self.dependencyProvider = [[RCTAppDependencyProvider alloc] init]; // if using codegen
+ *   [super scene:scene willConnectToSession:session options:connectionOptions];
+ * }
+ *
+ * - (NSURL *)bundleURL
+ * {
+ *   return [[RCTBundleURLProvider sharedSettings] jsBundleURLForBundleRoot:@"index"];
+ * }
+ *
+ * @end
+ * ```
+ *
+ * Required configuration (set before `[super scene:willConnectToSession:options:]`):
+ *   - `moduleName` — the AppRegistry component name to mount.
+ *   - `bundleURL` — override to return the JS bundle URL (raises if not implemented).
+ *
+ * Optional configuration:
+ *   - `initialProps` — props passed to the root component.
+ *   - `dependencyProvider` — codegen module/component provider.
+ *   - `automaticallyLoadReactNativeWindow` — defaults to `YES`; set to `NO` to call
+ *     `loadReactNativeWindow:` yourself after custom setup.
+ *
+ * Linking is forwarded automatically via `RCTLinkingManager`. Push notifications and other
+ * `UIApplicationDelegate` callbacks should remain on your AppDelegate.
+ *
+ * Overridable methods (inherited from `RCTDefaultReactNativeFactoryDelegate`):
+ *   - (UIViewController *)createRootViewController;
+ *   - (void)setRootView:(UIView *)rootView toRootViewController:(UIViewController *)rootViewController;
+ *   - (void)customizeRootView:(RCTRootView *)rootView;
+ *   - (NSDictionary<NSString *, Class<RCTComponentViewProtocol>> *)thirdPartyFabricComponents;
+ *   - (std::shared_ptr<facebook::react::TurboModule>)getTurboModule:(const std::string &)name
+ *                                                      jsInvoker:(std::shared_ptr<facebook::react::CallInvoker>)jsInvoker;
+ */
+@interface RCTSceneDelegate : RCTDefaultReactNativeFactoryDelegate <UIWindowSceneDelegate>
+
+/// The window object used to render UIViewControllers for this scene.
+@property (nonatomic, strong, nullable) UIWindow *window;
+
+#if !defined(RCT_REMOVE_LEGACY_ARCH)
+@property (nonatomic, nullable) RCTBridge *bridge
+    __attribute__((deprecated("The bridge is deprecated and will be removed when removing the legacy architecture.")));
+@property (nonatomic, nullable) RCTSurfacePresenterBridgeAdapter *bridgeAdapter __attribute__((
+    deprecated("The bridge adapter is deprecated and will be removed when removing the legacy architecture.")));
+#endif
+
+@property (nonatomic, strong, nullable) NSString *moduleName;
+@property (nonatomic, strong, nullable) NSDictionary *initialProps;
+@property (nonatomic, strong, nullable) RCTReactNativeFactory *reactNativeFactory;
+
+/// If `automaticallyLoadReactNativeWindow` is set to `true`, the React Native window is loaded in
+/// `scene:willConnectToSession:options:`.
+@property (nonatomic, assign) BOOL automaticallyLoadReactNativeWindow;
+
+- (RCTRootViewFactory *)rootViewFactory;
+
+/// Loads the React Native root view into `self.window` using UIScene connection options.
+- (void)loadReactNativeWindow:(UISceneConnectionOptions *_Nullable)connectionOptions;
+
+@end
+
+NS_ASSUME_NONNULL_END

packages/react-native/Libraries/AppDelegate/RCTSceneDelegate.mm

@@ -0,0 +1,68 @@
+/*
+ * Copyright (c) Meta Platforms, Inc. and affiliates.
+ *
+ * This source code is licensed under the MIT license found in the
+ * LICENSE file in the root directory of this source tree.
+ */
+
+#import "RCTSceneDelegate.h"
+
+#import <React/RCTLinkingManager.h>
+#import <React/RCTLog.h>
+#import <React/RCTRootView.h>
+#import <React/RCTUtils.h>
+
+@implementation RCTSceneDelegate
+
+- (instancetype)init
+{
+  if (self = [super init]) {
+    _automaticallyLoadReactNativeWindow = YES;
+  }
+  return self;
+}
+
+- (void)scene:(UIScene *)scene
+    willConnectToSession:(UISceneSession *)session
+                 options:(UISceneConnectionOptions *)connectionOptions
+{
+  if (![scene isKindOfClass:[UIWindowScene class]]) {
+    return;
+  }
+
+  self.reactNativeFactory = [[RCTReactNativeFactory alloc] initWithDelegate:self];
+
+  UIWindowScene *windowScene = (UIWindowScene *)scene;
+  self.window = [[UIWindow alloc] initWithWindowScene:windowScene];
+
+  if (self.automaticallyLoadReactNativeWindow) {
+    [self loadReactNativeWindow:connectionOptions];
+  }
+}
+
+- (void)loadReactNativeWindow:(UISceneConnectionOptions *)connectionOptions
+{
+  [self.reactNativeFactory startReactNativeWithModuleName:self.moduleName
+                                                 inWindow:self.window
+                                        initialProperties:self.initialProps
+                                        connectionOptions:connectionOptions];
+}
+
+- (RCTRootViewFactory *)rootViewFactory
+{
+  return self.reactNativeFactory.rootViewFactory;
+}
+
+#pragma mark - Linking (SceneDelegate lifecycle)
+
+- (void)scene:(UIScene *)scene openURLContexts:(NSSet<UIOpenURLContext *> *)URLContexts
+{
+  [RCTLinkingManager scene:scene openURLContexts:URLContexts];
+}
+
+- (void)scene:(UIScene *)scene continueUserActivity:(NSUserActivity *)userActivity
+{
+  [RCTLinkingManager scene:scene continueUserActivity:userActivity];
+}
+
+@end

packages/react-native/Libraries/AppDelegate/RCTUIConfiguratorProtocol.h

@@ -20,8 +20,8 @@ NS_ASSUME_NONNULL_BEGIN
 
 /**
  * This method can be used to customize the rootView that is passed to React Native.
- * A typical example is to override this method in the AppDelegate to change the background color.
- * To achieve this, add in your `AppDelegate.mm`:
+ * Override on your `RCTReactNativeFactoryDelegate` (e.g. in AppDelegate, SceneDelegate factory delegate, or
+ * `RCTAppDelegate` / `RCTSceneDelegate` subclass). Example:
  * ```
  * - (void)customizeRootView:(RCTRootView *)rootView
  * {